| タイトル | ： 出品者対応 その２ |
| 投稿日 | ： 2023/08/12(Sat) 22:05 |
| 投稿者 | ： ス〜 |
前回対応した分の修正です。
自己責任でお願いします。
YJ_REXPTN2.TXT の修正になります。
AE本体は終了しておく必要があります。
行番号は、原本を参考にしていますので、およその位置になります。
修正前は、YJ_REXPTN2.TXT をバックアップし、当修正が機能しない場合は戻してください。
------------------------------
●修正箇所１ 29行目付近
修正日を設定してください。
以前修正した場合は、特に必要ないようです。
Version=2023.8.12.0;
------------------------------
●修正箇所２ 624行目付近〜720行目付近
出品者検索の解析パターン全体の入れ替えです。
[] =================================================================
[] 出品者検索の解析パターン
[] パターン引数
[] ARG(0): ページHTML
[] ARG(1): 検索URL
[] =================================================================
[SEL_LST:MY_ACT src=ARG(0), ignorecase]
((?@USERID)|ゲスト)(?@ANYTAG)+\s*さん
[SEL_LST:ADULTENTRY src=ARG(0), ignorecase]
アダルトカテゴリに入ろうとしています
[SEL_LST:PAGEINFO src=ARG(0), ignorecase]
keys\s*:\s*{[^}]+}
[SEL_LST:PGN1 src=PAGEINFO(0), ignorecase]
,\s*pagenum:\s*'(\d+)'(?# [1]現ページ番号)
[SEL_LST:PGN2 src=PAGEINFO(0), ignorecase]
,\s*ins:\s*'(\d+)' (?# [2]総商品数)
[SEL_LST:PGN3 src=PAGEINFO(0), ignorecase]
,\s*n_sr:\s*'(\d+)'(?# [3]現ページの商品数)
[SEL_LST:RATE src=ARG(0), ignorecase]
class="Seller__link"\s*href="ht*ps://auctions\.yahoo\.co\.jp/jp/show/rating\?userID=(?@USERID)"[^>]*>評価</a>(?@ANYTAG)(-?[0-9,]+)<
[SEL_LST:ITEMAREA src=ARG(0), ignorecase]
<ul\s*class="Products__items">
.*
<footer class=
[SEL_LST:ITEMLST src=ITEMAREA, global, ignorecase]
(?:(?!class="Product__image").)+
((?:(?!class="Product__title").)+)
((?:(?!class="Product__price").)+)
((?:(?!<dd\s*class="Product__time).)+)
((?:(?!class="Product").)+)
[SEL_LST:SELLER src=ARG(0), ignorecase]
<link\s+rel="canonical"\s+href="(ht*ps://[^/]+/seller/((?@USERID)))
[SEL_LST]
flag_adult = !empty( ADULTENTRY(0) );
notfound = test( ARG(0), "以下の条件に一致する商品は見つかりませんでした。|条件に一致する検索結果はありません。|に一致する商品はありません。キーワードの一部を利用した結果を表示しています") ||
iif( !empty(PGN2(1)), PGN2(1)==0, 0 );// 総商品数はゼロ?
my_act= iif(MY_ACT(1)=="ゲスト", "$$guest", MY_ACT(1) );
max_itemn= parseint(PGN2(1));// 総商品数
cur_itemn= (parseint(PGN1(1))-1)*100+1; // 現ページ先頭商品番号
pged_itemn= cur_itemn+parseint(PGN3(1))-1; // 現ページ最終商品番号
itemid(#)= match(ITEMLST(#,1),'\s+data-auction-id="((?@ITEMID))"');// 商品ID
itemurl(#)= match(ITEMLST(#,1),'\s*href="([^"]+/' & itemid(#) & ')"' );// 商品URL
imgurl(#)= match(ITEMLST(#,1),'\s+ data-auction-img="([^">]+)');// 画像URL
tumburl(#)= iif( test(imgurl(#),'([^"]+/users/[^"]+)'), imgurl(#), '-' );// 画像URL(画像無し除外)
title(#)= match(ITEMLST(#,1),'\s+data-auction-title="([^">]+)'); // タイトル
slurl(#)= SELLER(1);
slid(#)= SELLER(2);
slrate(#) = iif( !empty(RATE(1)), parseint(RATE(1)), "" );// 出品者評価
icn_premium(#)= test(ARG(0),'class="seller__storeInfo"');// ストアアイコン
bids_txt(#) = match(ITEMLST(#,2),'data-cl-params="[^"]+,b=(\d+),[^"]+"');// 入札数文字列
bids(#) = parseint(bids_txt(#)); // 入札数(空は0とする)
lefttime_txt(#)= match(ITEMLST(#,4),'>\s*(?@ANYTAG)*([^\s<]+)'); // 残り時間文字列
lefttime_sec(#) = parseint(match(lefttime_txt(#),'(\d+)日' ))*86400 +// 秒単位残り時間
parseint(match(lefttime_txt(#),'(\d+)時間'))*3600 +
parseint(match(lefttime_txt(#),'(\d+)分' ))*60 +
parseint(match(lefttime_txt(#),'(\d+)秒' ));
sttime_unix= match(ITEMLST(#,2),'stm=(\d+)'); // 開始時刻(UNIX形式,日本時間)
cltime_unix= match(ITEMLST(#,3),' data-auction-endtime="(\d+)'); // 終了時刻(UNIX形式,日本時間)
catid(#) = match(ITEMLST(#,3),'data-auction-category="(\d+)"'); // カテゴリID
price(#)= match(ITEMLST(#,3),'data-auction-price="(\d+)"'); // 現在価格
buyprice_tmp(#)= match(ITEMLST(#,3),'<dd\s+class="Product__priceValue">\s*(?@PRICE)\s*<'); // 即決価格
buyprice(#) = iif( empty(buyprice_tmp(#)), "", parseint(buyprice_tmp(#)) ); // 即決価格
[]buyprice(#)= match(ITEMLST(#,3),'data-auction-buynowprice="(\d+)"'); // 即決価格(税抜き)
icn_buynow(#)= iif( parseint(buyprice_tmp(#)) > 0 , 1, 0 ); // 即決アイコン
icn_new(#)= test(ITEMLST(#,1),' class="Label Label--new'); // 新着アイコン
icn_att(#)= test(ITEMLST(#,1),' class="Label">未使用'); // 新品アイコン
icn_psf(#)= test(ITEMLST(#,1),' class="Label Label--free');// 送料無料アイコン
icn_img(#)= iif( !empty(tumburl(#))&&tumburl(#)!="-", "1", iif( !empty(imgurl(#)), "0", "" ) );// 画像有無アイコン
CHK0_items(#)= iif( !(empty(PGN1(1))||empty(PGN2(1))||empty(PGN3(1))),"", "[W5009]商品個数" );
CHK_title(#)= iif( !empty(title(#) ) ,"", "[W5009]タイトル" );
CHK_itemid(#)= iif( !empty(itemid(#) ) ,"", "[W5009]商品ID" );
CHK_price(#)= iif( !empty(price(#)) || !empty(buyprice(#)) ,"", "[W5009]現在価格" );
CHK_lefttime(#)= iif( !empty(lefttime_txt(#)) ,"", "[W5009]残り時間");
CHK_slid(#) = iif( !empty(slid(#)) ,"", "[W4009]出品者ID" );
CHK_bids(#) = iif( !empty(bids(#)) ,"", "[W4009]入札数" );